UltraPopupControlContainer Class

Imports Infragistics.Shared
Imports Infragistics.Win
Imports Infragistics.Win.Misc

Private Sub ultraPopupControlContainer1_Closed(ByVal sender As Object, ByVal e As System.EventArgs) Handles ultraPopupControlContainer1.Closed
    ' The Closed event is invoked when the
    ' popup has been closed and can be used to 
    ' destroy the control, perform an action, etc.

    System.Diagnostics.Debug.WriteLine("Closed")
End Sub

Private Sub ultraPopupControlContainer1_Opened(ByVal sender As Object, ByVal e As System.EventArgs) Handles ultraPopupControlContainer1.Opened
    ' The Opened event is invoked after the popup 
    ' has been displayed and can be used to further 
    ' initialize the popup

    ' For example, you can set focus to the control it displayed
    '
    Dim popup As UltraPopupControlContainer = CType(sender, UltraPopupControlContainer)

    ' the control that will be displayed can be initialized here
    If Not popup.PopupControl.ContainsFocus Then
        popup.PopupControl.Focus()
    End If
End Sub

Private Sub ultraPopupControlContainer1_Opening(ByVal sender As System.Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles ultraPopupControlContainer1.Opening
    Dim popup As UltraPopupControlContainer = CType(sender, UltraPopupControlContainer)

    Dim tree As TreeView = Me.treeList

    ' the control that will be displayed can be initialized here
    If Not popup.PopupControl Is tree Then
        popup.PopupControl = tree
    End If

    ' this Opening event will normally be used to initialize
    ' the control that will be dropped down
    Me.InitializeDropDownTree(tree)
End Sub

Private Sub InitializeDropDownTree(ByVal tree As TreeView)
    ' initialize the tree that we will be dropping down
    ' clear any existing nodes
    tree.Nodes.Clear()

    ' allow for full row selection
    tree.FullRowSelect = True
    tree.ShowLines = False
    tree.ShowRootLines = False

    ' only show a single border
    tree.BorderStyle = BorderStyle.FixedSingle

    ' create the nodes
    tree.Nodes.Add("New")
    tree.Nodes.Add("Open Existing")
    tree.Nodes.Add("Open Recent")

    ' select the first node
    tree.SelectedNode = tree.Nodes(0)

    ' size the control so it shows all the nodes
    Dim top As Integer = tree.Nodes(0).Bounds.Top
    Dim bottom As Integer = tree.Nodes(tree.Nodes.Count - 1).Bounds.Bottom
    tree.ClientSize = New Size(tree.ClientSize.Width, bottom - top)
End Sub

Private Sub treeList_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles treeList.KeyDown
    ' when the enter key is pressed invoke
    ' the tree's Click event
    If e.KeyCode = Keys.Return Then
        Me.InvokeOnClick(Me.treeList, EventArgs.Empty)
    ElseIf e.KeyCode = Keys.Escape Then
        ' then get the popup control container that is
        ' displaying the tree and close it
        Dim popup As UltraPopupControlContainer = UltraPopupControlContainer.FromControl(CType(sender, Control))

        If Not popup Is Nothing Then
            popup.Close()
        End If
    End If
End Sub

Private Sub treeList_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles treeList.Click
    Dim tree As TreeView = CType(sender, TreeView)

    ' get the selected node and perform some action on it
    Dim node As TreeNode = tree.SelectedNode

    System.Diagnostics.Debug.WriteLine("Node Clicked:" + node.Text)

    ' then get the popup control container that is
    ' displaying the tree and close it
    Dim popup As UltraPopupControlContainer = UltraPopupControlContainer.FromControl(tree)

    If Not popup Is Nothing Then
        popup.Close()
    End If
End Sub