ApplyChanges Property

Imports System
Imports System.Drawing
Imports System.IO
Imports System.Collections.Generic
Imports System.ComponentModel
Imports Infragistics.Shared
Imports Infragistics.Win
Imports Infragistics.Win.Misc
Imports Infragistics.Win.Misc.UltraWinNavigationBar
Imports System.Windows.Forms

Public Class FileSystemSupport

    ' Adds an UltraNavigationBarLocation and UltraTreeNode which each represent
    ' the current user, and adds "shortcuts" to the system's special folders under
    ' that location/node.
    Private Sub AddCurrentUserShortcut(ByVal rootLocation As UltraNavigationBarRootLocation, ByVal rootNode As UltraTreeNode)
        '  Get the username
        Dim userName As String = Me.UserName

        '  Get the constants of the Environment.SpecialFolder enumeration
        Dim values As Array = System.Enum.GetValues(GetType(Environment.SpecialFolder))

        '  Get the path to the users folder, based on the assumption that the parent 
        '  of the 'Desktop' special folder is the current user's root.
        Dim usersFolderPath As String = Me.UsersFolderPath

        '  Returns now if we can't get to the current user's root.
        If usersFolderPath.Length = 0 Or System.IO.Directory.Exists(usersFolderPath) = False Then Return

        '  Add an UltraNavigationBarLocation for the current user's root
        Dim userShortcutLocation As UltraNavigationBarLocation = rootLocation.Locations.Add(usersFolderPath, userName)
        userShortcutLocation.Settings.Appearance.Image = Me.GetImage(Images.Favorites)

        '  Set the TextButtonDisplayStyle property to 'ImageAndText' so that this
        '  location is a little more noticeable.
        userShortcutLocation.Settings.TextButtonDisplayStyle = TextButtonDisplayStyle.ImageAndText

        '  Add an UltraTreeNode for the current user's root
        Dim userShortcutNode As UltraTreeNode = rootNode.Nodes.Add(Nothing, userName)
        userShortcutNode.Override.NodeAppearance.Image = Me.GetImage(Images.Favorites)

        '  Create a ShortcutWrapper instance for each object and cross-reference them
        userShortcutLocation.Tag = New ShortcutWrapper(usersFolderPath, userShortcutNode, False)
        userShortcutNode.Tag = New ShortcutWrapper(usersFolderPath, userShortcutLocation, False)

        '  Iterate the special system folders, and add a shortcut for each of
        '  the children of the current user's root.
        Dim i As Integer
        For i = 0 To values.Length - 1

            Dim folderPath As String = System.Environment.GetFolderPath(values.GetValue(i))

            '  Some 'SpecialFolder' constants point to the same directory,
            '  so continue if we have already processed this one
            If (userShortcutLocation.Locations.Exists(folderPath)) Then Continue For

            If (folderPath.StartsWith(usersFolderPath)) Then

                '  Get the display text for this sub-directory
                Dim displayText As String = folderPath.Replace(String.Format("{0}\", usersFolderPath), String.Empty)
                If (displayText.Contains(PATH_SEPARATOR) = False) Then

                    '  Add an UltraNavigationBarLocation for the shorcut
                    Dim childLocation As UltraNavigationBarLocation = userShortcutLocation.Locations.Add(folderPath, displayText)
                    childLocation.Settings.Appearance.Image = Me.GetImage(Images.Shortcut)

                    '  Add an UltraTreeNode for the shorcut
                    Dim childNode As UltraTreeNode = userShortcutNode.Nodes.Add(Nothing, displayText)
                    childNode.Override.NodeAppearance.Image = Me.GetImage(Images.Shortcut)

                    '  Create a ShortcutWrapper instance for each object and cross-reference them
                    childLocation.Tag = New ShortcutWrapper(folderPath, childNode, True)
                    childNode.Tag = New ShortcutWrapper(folderPath, childLocation, True)
                End If
            End If
        Next
    End Sub

    Private ReadOnly Property UsersFolderPath() As String
        Get
            '  Get the path to the users folder, based on the assumption that the parent 
            '  of the 'Desktop' special folder is the current user's root.
            Dim path As String = System.Environment.GetFolderPath(Environment.SpecialFolder.Desktop)
            Dim usersFolder As DirectoryInfo = Directory.GetParent(path)

            If usersFolder Is Nothing Then Return String.Empty

            Return usersFolder.FullName

        End Get
    End Property

    ' Handles the UltraNavigationBar's 'ExitingEditMode' event.
    Private Sub OnNavigationBarExitingEditMode(ByVal sender As Object, ByVal e As ExitingEditModeEventArgs)

        '   If the edit mode session was canceled, don't proceed.
        If e.Cancel Or e.ApplyChanges = False Then Return

        '  Determine whether the edit mode text contains the special folders root
        '  if it does, we will replace it with the shortcut to the users folder,
        '  so that when edit mode is exited, the shortcut location is selected.
        Dim path As String = e.NavigationPath
        Dim usersFolderPath As String = Me.UsersFolderPath
        Dim userName As String = Me.UserName

        If (path.Contains(usersFolderPath)) Then
            path = path.Replace(usersFolderPath, userName)
            e.Editor.Value = path
        End If
    End Sub

    ' Handles the UltraNavigationBar's 'EnteringEditMode' event.
    Private Sub OnNavigationBarEnteringEditMode(ByVal sender As Object, ByVal e As CancelableEditModeEventArgs)

        '  Determine whether the edit mode text contains the name of the users folder
        '  shortcut; if it does, we will replace it with the special folders root,
        '  so that when edit mode is entered, the path to the actual folder appears.
        Dim path As String = e.NavigationPath
        Dim usersFolderPath As String = Me.UsersFolderPath
        Dim userName As String = Me.UserName

        If (path.Contains(userName) AndAlso path.Length > userName.Length) Then
            path = path.Replace(userName, usersFolderPath)
            e.NavigationPath = path
        End If
    End Sub

End Class